Solidity

Solidity Payable Function

• A payable function is a function that can receive Ether together with the call. The amount sent is available in msg.value (in wei) and is added to the contract’s balance automatically.
• A function without the payable keyword rejects any Ether sent to it – the transaction reverts.
• A payable function can also be called with zero Ether; use require(msg.value > 0) (or an exact amount) if a payment is mandatory.
• The contract’s current balance is address(this).balance.

All about Payable

• payable functions – function deposit() external payable { } – receive Ether with a call.
• receive / payable fallback – receive plain Ether that is sent without calling a named function (Chapter 23). The old unnamed function () payable syntax was replaced by receive() and fallback() in Solidity 0.6.0.
• payable constructor – lets Ether be sent at deployment (Chapter 17).
• address payable – the address type that can receive Ether through transfer/send. Convert with payable(addr), e.g. payable(msg.sender).

Methods for Sending Ether

Sending Ether Safely

• Checks – Effects – Interactions: first check conditions, then update your contract’s state (e.g. set the balance to 0), and only then send Ether. This prevents reentrancy, where the recipient calls back into your function before the state is updated.
• Withdrawal (pull) pattern: instead of pushing payments to many users in one loop, record what each user is owed and let each user withdraw it. One failing recipient then cannot block everyone else.
• Always check the result of send and call.
• Amounts are in wei; write 1 ether or 0.5 ether for readability.

Example : Deposits and Safe Withdrawals

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

contract EtherWallet {
    mapping(address => uint) public balances;

    event Deposit(address indexed user, uint amount);
    event Withdrawal(address indexed user, uint amount);

    // payable: accepts Ether, amount in msg.value
    function deposit() external payable {
        require(msg.value > 0, "Send some Ether");
        balances[msg.sender] += msg.value;
        emit Deposit(msg.sender, msg.value);
    }

    // withdrawal (pull) pattern with checks-effects-interactions
    function withdraw(uint amount) external {
        require(balances[msg.sender] >= amount, "Insufficient balance");   // checks
        balances[msg.sender] -= amount;                                      // effects
        (bool ok, ) = payable(msg.sender).call{value: amount}("");          // interaction
        require(ok, "Transfer failed");
        emit Withdrawal(msg.sender, amount);
    }

    function contractBalance() external view returns (uint) {
        return address(this).balance;
    }

    // plain Ether sent to the contract is credited to the sender
    receive() external payable {
        balances[msg.sender] += msg.value;
        emit Deposit(msg.sender, msg.value);
    }
}

Key Takeaways

The PDF E-Notes are the earlier printable version of this chapter. The notes on this page are the latest, revised version.

Video : Payable Functions and Sending Ether

Resource File

• Chapter 24 : Solidity File

Question / Answer (15 questions)

MCQ Test : Check Your Understanding (5 questions)

Select an option and press Check Answer, or answer all questions and press Submit Test to see your score. Each answer comes with an explanation.

Bibliography/References

The notes, questions and MCQs on this page are original explanations written for this course. The works listed below were consulted and are cited for attribution and further reading. Product names, logos and trademarks belong to their respective owners. Short quotations, where used, are marked and attributed.

1. Solidity Team. (n.d.). Types (value types, reference types, mappings, operators, conversions). Solidity Documentation. https://docs.soliditylang.org/en/latest/types.html
2. Solidity Team. (n.d.). Units and Globally Available Variables. Solidity Documentation. https://docs.soliditylang.org/en/latest/units-and-global-variables.html
3. Solidity Team. (n.d.). Security Considerations. Solidity Documentation. https://docs.soliditylang.org/en/latest/security-considerations.html
4. ethereum.org. (n.d.). Smart contract security. Ethereum Developer Documentation. https://ethereum.org/en/developers/docs/smart-contracts/security/
5. Showwcase. (n.d.). Payable functions in Solidity. https://www.showwcase.com/show/33658/payable-functions-in-solidity
6. Modi, R. (2018). Solidity Programming Essentials: A beginner’s guide to build smart contracts for Ethereum and blockchain. Packt Publishing. ISBN 978-1-78883-138-3.