Solidity

String

• Solidity data types are classified as value types and reference types. A string is a reference type: the variable refers to where the text is stored.
• A string is a dynamically sized sequence of characters – letters, digits, spaces and symbols.
• Strings are stored as UTF-8 encoded bytes. Internally string is the same as bytes, but it does not allow index access or a .length member.
• Both double quotes "Hello" and single quotes 'Hello' can be used for string literals. Normal literals may contain only printable ASCII; for other characters use a Unicode literal: unicode"नमस्ते ₹".

String and Memory

• Because a string has no fixed size, you must tell the compiler where it is kept when it is used in a function: memory, calldata or storage.
• memory is a temporary area (much like RAM). A function can use memory while it runs; after execution the memory is wiped. storage keeps data between calls.
• Return values of type string are always declared string memory.
• Parameters of external functions can use string calldata, which is read-only and cheaper.

Common String Operations

Bytes to String Conversion – bytes can be converted to a string with the string() conversion:
bytes memory bstr = new bytes(10);
string memory message = string(bstr);

Escape Characters

Example : Working with Strings

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

contract StringDemo {
    string public greeting = "Hello";        // stored permanently in storage

    function setGreeting(string calldata text) external {
        greeting = text;                      // calldata -> storage copy
    }

    function byteLength(string calldata text) external pure returns (uint) {
        return bytes(text).length;            // number of UTF-8 bytes
    }

    function isEqual(string memory a, string memory b) public pure returns (bool) {
        return keccak256(bytes(a)) == keccak256(bytes(b));
    }

    function fullName(string memory first, string memory last) public pure returns (string memory) {
        return string.concat(first, " ", last);
    }

    function firstLetter(string memory text) public pure returns (bytes1) {
        require(bytes(text).length > 0, "Empty string");
        return bytes(text)[0];
    }

    function rupee() public pure returns (string memory, uint) {
        string memory symbol = unicode"₹";
        return (symbol, bytes(symbol).length);   // ("₹", 3)
    }
}

Key Takeaways

The PDF E-Notes are the earlier printable version of this chapter. The notes on this page are the latest, revised version.

Video : Strings in Solidity

Resource File

• Chapter 9 : Solidity File

Question / Answer (15 questions)

MCQ Test : Check Your Understanding (5 questions)

Select an option and press Check Answer, or answer all questions and press Submit Test to see your score. Each answer comes with an explanation.

Bibliography/References

The notes, questions and MCQs on this page are original explanations written for this course. The works listed below were consulted and are cited for attribution and further reading. Product names, logos and trademarks belong to their respective owners. Short quotations, where used, are marked and attributed.

1. Solidity Team. (n.d.). Types (value types, reference types, mappings, operators, conversions). Solidity Documentation. https://docs.soliditylang.org/en/latest/types.html
2. Solidity Team. (n.d.). Cheatsheet. Solidity Documentation. https://docs.soliditylang.org/en/latest/cheatsheet.html
3. GeeksforGeeks. (n.d.). Solidity – Strings. https://www.geeksforgeeks.org/solidity-strings/
4. Modi, R. (2018). Solidity Programming Essentials: A beginner’s guide to build smart contracts for Ethereum and blockchain. Packt Publishing. ISBN 978-1-78883-138-3.